Add tests & fixes for Code Fixes

src/FsAutoComplete/CodeFixes/ChangeDerefBangToValue.fs

@@ -0,0 +1,82 @@
+/// replace use of ! operator on ref cells with calls to .Value
+module FsAutoComplete.CodeFix.ChangeDerefBangToValue
+
+open FsToolkit.ErrorHandling
+open FsAutoComplete.CodeFix.Types
+open FsAutoComplete
+open FsAutoComplete.LspHelpers
+open FSharp.Compiler.Syntax
+open FSharp.Compiler.Text.Range
+open FSharp.UMX
+
+// let fix (getParseResultsForFile: GetParseResultsForFile) (getLineText: GetLineText): CodeFix =
+//   fun codeActionParams ->
+//     asyncResult {
+//       let fileName = codeActionParams.TextDocument.GetFilePath() |> Utils.normalizePath
+//       let selectionRange = protocolRangeToRange (codeActionParams.TextDocument.GetFilePath()) codeActionParams.Range
+//       let! parseResults, line, lines = getParseResultsForFile fileName selectionRange.Start
+//       let! derefRange = parseResults.GetParseResults.TryRangeOfRefCellDereferenceContainingPos selectionRange.Start |> Result.ofOption (fun _ -> "No deref found at that pos")
+//       let! exprRange = parseResults.GetParseResults.TryRangeOfExpressionBeingDereferencedContainingPos selectionRange.Start |> Result.ofOption (fun _ -> "No expr found at that pos")
+//       let combinedRange = FSharp.Compiler.Text.Range.unionRanges derefRange exprRange
+//       let protocolRange = fcsRangeToLsp combinedRange
+//       let! badString = getLineText lines protocolRange
+//       let replacementString = badString.[1..] + ".Value"
+//       return [
+//         { Title = title
+//           File = codeActionParams.TextDocument
+//           SourceDiagnostic = None
+//           Kind = FixKind.Refactor
+//           Edits = [| { Range = protocolRange
+//                        NewText = replacementString } |] }
+//       ]
+//     }
+
+/// adopted from `dotnet/fsharp` -> `FSharp.Compiler.CodeAnalysis.FSharpParseFileResults.TryRangeOfExpressionBeingDereferencedContainingPos`
+let private tryGetRangeOfDeref input derefPos =
+    SyntaxTraversal.Traverse(derefPos, input, { new SyntaxVisitorBase<_>() with 
+        member _.VisitExpr(_, _, defaultTraverse, expr) =
+            match expr with
+            | SynExpr.App(_, false, SynExpr.Ident funcIdent, expr, _) ->
+                if funcIdent.idText = "op_Dereference" && rangeContainsPos funcIdent.idRange derefPos then
+                    Some (funcIdent.idRange, expr.Range)
+                else
+                    None
+            | _ -> defaultTraverse expr })
+
+let title = "Use `.Value` instead of dereference operator"
+let fix
+  (getParseResultsForFile: GetParseResultsForFile)
+  (getLineText: GetLineText)
+  : CodeFix =
+  Run.ifDiagnosticByCode
+    (Set.ofList ["3370"])
+    (fun diagnostic codeActionParams -> asyncResult {
+      let fileName = codeActionParams.TextDocument.GetFilePath() |> Utils.normalizePath
+
+      let derefOpRange = protocolRangeToRange (UMX.untag fileName) diagnostic.Range
+      let! parseResults, _, _ = getParseResultsForFile fileName derefOpRange.Start
+
+      let! (derefOpRange', exprRange) = 
+        tryGetRangeOfDeref parseResults.GetParseResults.ParseTree derefOpRange.End
+        |> Result.ofOption (fun _ -> "No deref found at that pos")
+      assert(derefOpRange = derefOpRange')
+
+      return [
+        { 
+          Title = title
+          File = codeActionParams.TextDocument
+          SourceDiagnostic = None
+          Kind = FixKind.Refactor
+          Edits = [| 
+            // remove leading `!` (and whitespaces after `!`)
+            { Range = { Start = fcsPosToLsp derefOpRange'.Start; End = fcsPosToLsp exprRange.Start }
+              NewText = "" } 
+            // Append trailing `.Value`
+            { Range = 
+                let lspPos = fcsPosToLsp exprRange.End
+                { Start = lspPos; End = lspPos }
+              NewText = ".Value" }
+          |] 
+        }
+      ]
+    })

src/FsAutoComplete/FsAutoComplete.Lsp.fs

@@ -888,7 +888,7 @@ type FSharpLspServer(backgroundServiceEnabled: bool, state: State, lspClient: FS
            MakeOuterBindingRecursive.fix tryGetParseResultsForFile getLineText
            AddMissingRecKeyword.fix getFileLines getLineText
            ConvertBangEqualsToInequality.fix getRangeText
-           ReplaceBangWithValueFunction.fix tryGetParseResultsForFile getLineText
+           ChangeDerefBangToValue.fix tryGetParseResultsForFile getLineText
            RemoveUnusedBinding.fix tryGetParseResultsForFile
            AddTypeToIndeterminateValue.fix tryGetParseResultsForFile tryGetProjectOptions
            ChangeTypeOfNameToNameOf.fix tryGetParseResultsForFile

test/FsAutoComplete.Tests.Lsp/CodeFixTests.fs

@@ -216,6 +216,71 @@ let private addTypeToIndeterminateValueTests state =
         """
   ])
 
+let private changeDerefBangToValueTests state =
+  serverTestList (nameof ChangeDerefBangToValue) state defaultConfigDto None (fun server -> [
+    let selectCodeFix = CodeFix.withTitle ChangeDerefBangToValue.title
+    testCaseAsync "can replace ! with .Value" <|
+      CodeFix.check server
+        """
+        let rv = ref 5
+        let v = $0!rv
+        """
+        (Diagnostics.expectCode "3370")
+        selectCodeFix
+        """
+        let rv = ref 5
+        let v = rv.Value
+        """
+    testCaseAsync "can replace ! with .Value when parens" <|
+      CodeFix.check server
+        """
+        let rv = ref 5
+        let v = $0!(rv)
+        """
+        (Diagnostics.expectCode "3370")
+        selectCodeFix
+        """
+        let rv = ref 5
+        let v = (rv).Value
+        """
+    testCaseAsync "can replace ! with .Value when function in parens" <|
+      CodeFix.check server
+        """
+        let fr a = ref a
+        let v = $0!(fr 5)
+        """
+        (Diagnostics.expectCode "3370")
+        selectCodeFix
+        """
+        let fr a = ref a
+        let v = (fr 5).Value
+        """
+    testCaseAsync "can replace ! with .Value when space between ! and variable" <|
+      CodeFix.check server
+        """
+        let rv = ref 5
+        let v = $0! rv
+        """
+        (Diagnostics.expectCode "3370")
+        selectCodeFix
+        """
+        let rv = ref 5
+        let v = rv.Value
+        """
+    testCaseAsync "can replace ! with .Value when when parens and space between ! and variable" <|
+      CodeFix.check server
+        """
+        let rv = ref 5
+        let v = $0! (rv)
+        """
+        (Diagnostics.expectCode "3370")
+        selectCodeFix
+        """
+        let rv = ref 5
+        let v = (rv).Value
+        """
+  ])
+
 let private changeEqualsInFieldTypeToColonTests state = 
   serverTestList (nameof ChangeEqualsInFieldTypeToColon) state defaultConfigDto None (fun server -> [
     let selectCodeFix = CodeFix.withTitle ChangeEqualsInFieldTypeToColon.title
@@ -1211,6 +1276,7 @@ let tests state = testList "CodeFix tests" [
   addMissingRecKeywordTests state
   addNewKeywordToDisposableConstructorInvocationTests state
   addTypeToIndeterminateValueTests state
+  changeDerefBangToValueTests state
   changeEqualsInFieldTypeToColonTests state
   changePrefixNegationToInfixSubtractionTests state
   changeRefCellDerefToNotTests state