-
Notifications
You must be signed in to change notification settings - Fork 1
/
build.gradle.kts
178 lines (163 loc) · 5.28 KB
/
build.gradle.kts
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
import com.github.benmanes.gradle.versions.updates.gradle.GradleReleaseChannel.CURRENT
import org.gradle.api.plugins.BasePlugin.BUILD_GROUP
import org.jetbrains.dokka.gradle.DokkaTask
import java.util.Locale
group = "com.github.mpe85"
version = "1.4.1-SNAPSHOT"
val additionalTestToolchains = listOf(11, 17, 21, 22)
val gitUrl = "https://github.com/mpe85/${project.name}"
val gitScmUrl = "https://github.com/mpe85/${project.name}.git"
plugins {
kotlin("jvm") version "2.0.20"
id("io.gitlab.arturbosch.detekt") version "1.23.7"
id("org.jetbrains.dokka") version "1.9.20"
id("org.jetbrains.kotlinx.kover") version "0.8.3"
id("org.jlleitschuh.gradle.ktlint") version "12.1.1"
id("org.gradle.maven-publish")
id("org.gradle.signing")
id("com.github.ben-manes.versions") version "0.51.0"
}
repositories {
mavenCentral()
}
dependencies {
implementation("net.bytebuddy:byte-buddy:1.15.1")
implementation("org.greenrobot:eventbus-java:3.3.1")
implementation("com.ibm.icu:icu4j:75.1")
implementation("org.jetbrains.kotlin:kotlin-reflect:2.0.20")
implementation("org.jetbrains.kotlin:kotlin-stdlib-jdk8:2.0.20")
testImplementation("org.junit.jupiter:junit-jupiter:5.11.0")
testImplementation("io.kotest:kotest-assertions-core:5.9.1")
testImplementation("io.kotest:kotest-property:5.9.1")
testImplementation("io.kotest:kotest-runner-junit5:5.9.1")
testImplementation("io.mockk:mockk:1.13.12")
}
kotlin {
explicitApi()
}
kover {
reports {
total {
html {
onCheck = true
}
xml {
onCheck = true
}
verify {
onCheck = true
}
}
}
}
additionalTestToolchains.forEach {
tasks.create<Test>("testOn$it") {
group = JavaBasePlugin.VERIFICATION_GROUP
javaLauncher.set(
javaToolchains.launcherFor {
languageVersion.set(JavaLanguageVersion.of(it))
},
)
}
}
val javadocJar by tasks.creating(Jar::class) {
group = BUILD_GROUP
dependsOn("dokkaHtml")
archiveClassifier.set("javadoc")
from(tasks.getByName<DokkaTask>("dokkaHtml").outputDirectory)
}
val sourcesJar by tasks.creating(Jar::class) {
group = BUILD_GROUP
dependsOn("classes")
archiveClassifier.set("sources")
from(sourceSets.main.get().allSource)
}
artifacts {
archives(javadocJar)
archives(sourcesJar)
}
tasks {
jar {
manifest {
attributes["Implementation-Title"] = project.name
attributes["Implementation-Version"] = project.version
attributes["Implementation-Vendor"] = project.group
attributes["Created-By"] = "${System.getProperty("java.version")} (${System.getProperty("java.vendor")})"
attributes["Automatic-Module-Name"] = "${project.group}.${project.name}"
}
}
dependencyUpdates {
revision = "release"
checkConstraints = false
gradleReleaseChannel = CURRENT.id
rejectVersionIf {
candidate.version.isNonStable()
}
}
withType<Test>().configureEach {
useJUnitPlatform()
testLogging {
events("passed", "skipped", "failed")
}
}
}
publishing {
repositories {
maven {
val releasesRepoUrl = "https://s01.oss.sonatype.org/content/repositories/releases/"
val snapshotsRepoUrl = "https://s01.oss.sonatype.org/content/repositories/snapshots/"
url = uri(if (version.toString().endsWith("SNAPSHOT")) snapshotsRepoUrl else releasesRepoUrl)
credentials {
username = "ossrhUsername".property()
password = "ossrhPassword".property()
}
}
}
publications {
register<MavenPublication>("mavenJava") {
from(components["java"])
artifact(sourcesJar) {
classifier = "sources"
}
artifact(javadocJar) {
classifier = "javadoc"
}
groupId = "$group"
artifactId = project.name
version = "${project.version}"
pom {
name.set("Grampa")
description.set("Grampa")
url.set(gitUrl)
licenses {
license {
name.set("MIT")
url.set("$gitUrl/blob/main/LICENSE")
}
}
developers {
developer {
id.set("mpe85")
name.set("Marco Perazzo")
email.set("marco.perazzo85@gmail.com")
}
}
scm {
connection.set(gitScmUrl)
developerConnection.set(gitScmUrl)
url.set(gitUrl)
}
}
}
}
}
signing {
sign(publishing.publications["mavenJava"])
}
fun String.isNonStable(): Boolean {
val stableKeyword = listOf("RELEASE", "FINAL", "GA").any { uppercase(Locale.ENGLISH).contains(it) }
val regex = "^[0-9,.v-]+(-r)?$".toRegex()
val isStable = stableKeyword || regex.matches(this)
return isStable.not()
}
fun String.property() = if (hasProperty(this)) property(this)?.toString() else null