-
-
Notifications
You must be signed in to change notification settings - Fork 29
/
CMakeLists.txt
executable file
·270 lines (230 loc) · 8.55 KB
/
CMakeLists.txt
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
cmake_minimum_required(VERSION 3.12)
project("CLIP.cpp" C CXX)
set(CMAKE_EXPORT_COMPILE_COMMANDS ON)
if (NOT XCODE AND NOT MSVC AND NOT CMAKE_BUILD_TYPE)
set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type" FORCE)
set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release" "MinSizeRel" "RelWithDebInfo")
endif()
set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
#
# Option list
#
# general
option(CLIP_STATIC "CLIP: static link libraries" OFF)
option(CLIP_NO_EXAMPLES "CLIP: do not build examples" OFF)
option(CLIP_NO_TESTS "CLIP: do not build tests" OFF)
option(CLIP_NATIVE "CLIP: enable -march=native flag" ON)
option(CLIP_LTO "CLIP: enable link time optimization" OFF)
# debug
option(CLIP_ALL_WARNINGS "CLIP: enable all compiler warnings" OFF)
option(CLIP_ALL_WARNINGS_3RD_PARTY "CLIP: enable all compiler warnings in 3rd party libs" OFF)
option(CLIP_GPROF "CLIP: enable gprof" OFF)
# sanitizers
option(CLIP_SANITIZE_THREAD "CLIP: enable thread sanitizer" OFF)
option(CLIP_SANITIZE_ADDRESS "CLIP: enable address sanitizer" OFF)
option(CLIP_SANITIZE_UNDEFINED "CLIP: enable undefined sanitizer" OFF)
# instruction set specific
option(CLIP_AVX "CLIP: enable AVX" ON)
option(CLIP_AVX2 "CLIP: enable AVX2" ON)
option(CLIP_FMA "CLIP: enable FMA" ON)
option(CLIP_AVX512 "clip: enable AVX512" OFF)
option(CLIP_AVX512_VBMI "clip: enable AVX512-VBMI" OFF)
option(CLIP_AVX512_VNNI "clip: enable AVX512-VNNI" OFF)
# in MSVC F16C is implied with AVX2/AVX512
if (NOT MSVC)
option(CLIP_F16C "clip: enable F16C" ON)
endif()
# 3rd party libs
option(CLIP_ACCELERATE "CLIP: enable Accelerate framework" ON)
option(CLIP_OPENBLAS "CLIP: use OpenBLAS" OFF)
#
# Compile flags
#
set(CMAKE_CXX_STANDARD_REQUIRED true)
set(CMAKE_C_STANDARD_REQUIRED true)
set(THREADS_PREFER_PTHREAD_FLAG ON)
find_package(Threads REQUIRED)
if (NOT MSVC)
if (CLIP_SANITIZE_THREAD)
add_compile_options(-fsanitize=thread)
link_libraries(-fsanitize=thread)
endif()
if (CLIP_SANITIZE_ADDRESS)
add_compile_options(-fsanitize=address -fno-omit-frame-pointer)
link_libraries(-fsanitize=address)
endif()
if (CLIP_SANITIZE_UNDEFINED)
add_compile_options(-fsanitize=undefined)
link_libraries(-fsanitize=undefined)
endif()
endif()
if (APPLE AND CLIP_ACCELERATE)
find_library(ACCELERATE_FRAMEWORK Accelerate)
if (ACCELERATE_FRAMEWORK)
message(STATUS "Accelerate framework found")
add_compile_definitions(GGML_USE_ACCELERATE)
set(CLIP_EXTRA_LIBS ${CLIP_EXTRA_LIBS} ${ACCELERATE_FRAMEWORK})
else()
message(WARNING "Accelerate framework not found")
endif()
endif()
if (CLIP_OPENBLAS)
if (CLIP_STATIC)
set(BLA_STATIC ON)
endif()
set(BLA_VENDOR OpenBLAS)
find_package(BLAS)
if (BLAS_FOUND)
message(STATUS "OpenBLAS found")
add_compile_definitions(GGML_USE_OPENBLAS)
add_link_options(${BLAS_LIBRARIES})
else()
message(WARNING "OpenBLAS not found")
endif()
endif()
if (CLIP_ALL_WARNINGS)
if (NOT MSVC)
set(c_flags
-Wall
-Wextra
-Wpedantic
-Wcast-qual
-Wdouble-promotion
-Wshadow
-Wstrict-prototypes
-Wpointer-arith
-Wno-unused-function
)
set(cxx_flags
-Wall
-Wextra
-Wpedantic
-Wcast-qual
-Wno-unused-function
)
else()
# todo : msvc
endif()
add_compile_options(
"$<$<COMPILE_LANGUAGE:C>:${c_flags}>"
"$<$<COMPILE_LANGUAGE:CXX>:${cxx_flags}>"
)
endif()
add_compile_options(-Wno-format -O3)
if (CLIP_LTO)
include(CheckIPOSupported)
check_ipo_supported(RESULT result OUTPUT output)
if (result)
set(CMAKE_INTERPROCEDURAL_OPTIMIZATION TRUE)
else()
message(WARNING "IPO is not supported: ${output}")
endif()
endif()
# Architecture specific
# TODO: probably these flags need to be tweaked on some architectures
# feel free to update the Makefile for your architecture and send a pull request or issue
message(STATUS "CMAKE_SYSTEM_PROCESSOR: ${CMAKE_SYSTEM_PROCESSOR}")
if (NOT MSVC)
if (CLIP_STATIC)
add_link_options(-static)
if (MINGW)
add_link_options(-static-libgcc -static-libstdc++)
endif()
endif()
if (CLIP_GPROF)
add_compile_options(-pg)
endif()
if (CLIP_NATIVE)
add_compile_options(-march=native)
endif()
endif()
if (${CMAKE_SYSTEM_PROCESSOR} MATCHES "arm" OR ${CMAKE_SYSTEM_PROCESSOR} MATCHES "aarch64")
message(STATUS "ARM detected")
if (MSVC)
# TODO: arm msvc?
else()
if (${CMAKE_SYSTEM_PROCESSOR} MATCHES "aarch64")
add_compile_options(-mcpu=native)
endif()
# TODO: armv6,7,8 version specific flags
endif()
elseif (${CMAKE_SYSTEM_PROCESSOR} MATCHES "^(x86_64|i686|AMD64)$")
message(STATUS "x86 detected")
if (MSVC)
if (CLIP_AVX512)
add_compile_options($<$<COMPILE_LANGUAGE:C>:/arch:AVX512>)
add_compile_options($<$<COMPILE_LANGUAGE:CXX>:/arch:AVX512>)
# MSVC has no compile-time flags enabling specific
# AVX512 extensions, neither it defines the
# macros corresponding to the extensions.
# Do it manually.
if (CLIP_AVX512_VBMI)
add_compile_definitions($<$<COMPILE_LANGUAGE:C>:__AVX512VBMI__>)
add_compile_definitions($<$<COMPILE_LANGUAGE:CXX>:__AVX512VBMI__>)
endif()
if (CLIP_AVX512_VNNI)
add_compile_definitions($<$<COMPILE_LANGUAGE:C>:__AVX512VNNI__>)
add_compile_definitions($<$<COMPILE_LANGUAGE:CXX>:__AVX512VNNI__>)
endif()
elseif (CLIP_AVX2)
add_compile_options($<$<COMPILE_LANGUAGE:C>:/arch:AVX2>)
add_compile_options($<$<COMPILE_LANGUAGE:CXX>:/arch:AVX2>)
elseif (CLIP_AVX)
add_compile_options($<$<COMPILE_LANGUAGE:C>:/arch:AVX>)
add_compile_options($<$<COMPILE_LANGUAGE:CXX>:/arch:AVX>)
endif()
else()
if (CLIP_F16C)
add_compile_options(-mf16c)
endif()
if (CLIP_FMA)
add_compile_options(-mfma)
endif()
if (CLIP_AVX)
add_compile_options(-mavx)
endif()
if (CLIP_AVX2)
add_compile_options(-mavx2)
endif()
if (CLIP_AVX512)
add_compile_options(-mavx512f)
add_compile_options(-mavx512bw)
endif()
if (CLIP_AVX512_VBMI)
add_compile_options(-mavx512vbmi)
endif()
if (CLIP_AVX512_VNNI)
add_compile_options(-mavx512vnni)
endif()
endif()
else()
# TODO: support PowerPC
message(STATUS "Unknown architecture")
endif()
#
# Build libraries
#
if (MSVC)
add_compile_definitions(_CRT_SECURE_NO_WARNINGS)
endif()
add_subdirectory(ggml)
if (BUILD_SHARED_LIBS)
set_target_properties(ggml PROPERTIES POSITION_INDEPENDENT_CODE ON)
endif()
add_library(clip
clip.cpp
clip.h)
target_include_directories(clip PUBLIC .)
target_compile_features(clip PUBLIC cxx_std_20) # don't bump
target_link_libraries(clip PRIVATE ggml ${CLIP_EXTRA_LIBS})
if (BUILD_SHARED_LIBS)
set_target_properties(clip PROPERTIES POSITION_INDEPENDENT_CODE ON)
target_compile_definitions(clip PRIVATE CLIP_SHARED CLIP_BUILD)
endif()
add_subdirectory(models)
if (NOT CLIP_NO_EXAMPLES)
add_subdirectory(examples)
endif()
if (NOT CLIP_NO_TESTS)
add_subdirectory(tests)
endif()