How to add glad2 as a dependency using CMake with FetchContent_Declare and FetchContent_MakeAvailable?

[junglie85]

How should we use FetchContent_Declare and FetchContent_MakeAvailable to include glad2?

I've tried the following but it doesn't build:

if ((NOT DEFINED BT_GLAD_LIBS) OR (NOT DEFINED BT_GLAD_INCLUDE_DIRS))
    FetchContent_Declare(
        glad
        GIT_REPOSITORY https://github.com/Dav1dde/glad.git
        GIT_TAG glad2
        GIT_PROGRESS TRUE
    )

    message("####################### IN GLAD ###############################")

    set(GLAD_PROFILE "core" CACHE STRING "OpenGL profile")
    set(GLAD_API "gl=" CACHE STRING "API type/version pairs, like \"gl=3.2,gles=\", no version means latest")
    set(GLAD_GENERATOR "c" CACHE STRING "Language to generate the binding for")
    # set(glad_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
    
    FetchContent_MakeAvailable(glad)
    
    set(BT_GLAD_LIBS glad)
	set(BT_GLAD_INCLUDE_DIRS ${glad_SOURCE_DIR}/include)
endif ()

Which results in the following output:

[cmake] ####################### IN GLAD ###############################
[cmake] -- Populating glad
[cmake] -- Configuring done (0.0s)
[cmake] -- Generating done (0.0s)
[cmake] -- Build files have been written to: D:/mario/build/_deps/glad-subbuild
[cmake] [0/7] Performing update step for 'glad-populate'
[cmake] [1/7] No patch step for 'glad-populate'
[cmake] [3/7] No configure step for 'glad-populate'
[cmake] [4/7] No build step for 'glad-populate'
[cmake] [5/7] No install step for 'glad-populate'
[cmake] [6/7] No test step for 'glad-populate'
[cmake] [7/7] Completed 'glad-populate'

[Dav1dde]

Not sure, I am not familiar with cmake enough, maybe someone else can help. In hindsight I shouldn't have added it to glad2 at all.

I recommend you to manually generate and just check in the generated code, there is no gain to include glad into the build process, it just means your build process now also depends on python and jinja2.

[nolmoonen]

As the original poster alludes to, the GLAD CMakeLists.txt is not in the project root, so a workaround is needed. With the SOURCE_SUBDIR option of FetchContent_Declare you can specify an alternative directory to use as the top of the CMake source tree, which is relative to the top directory of the populated content. So a full example would be:

FetchContent_Declare(
    glad
    GIT_REPOSITORY https://github.com/Dav1dde/glad.git
    GIT_TAG        658f48e72aee3c6582e80b05ac0f8787a64fe6bb #v2.0.6
    GIT_PROGRESS   TRUE
    SOURCE_SUBDIR  cmake
)
FetchContent_MakeAvailable(glad)
glad_add_library(glad_gl_core_43 STATIC REPRODUCIBLE LOADER API gl:core=4.3)
target_link_libraries(my_target PRIVATE glad_gl_core_43)