Add reporter and license

Author: kazk

CodewarsReporter.cfc

@@ -0,0 +1,98 @@
+/**
+ * Renders TestResult from TestBox in Codewars format.
+ * Based on `CLIRenderer@testbox-commands`.
+ */
+component {
+
+	/**
+	 * @print a print buffer to use
+	 * @testData test results from TestBox
+	 */
+	function render( print, testData ){
+		for ( thisBundle in testData.bundleStats ) {
+			// Check if the bundle threw a global exception
+			if ( !isSimpleValue( thisBundle.globalException ) ) {
+				var message = escapeLF(
+					"#thisBundle.globalException.type#:#thisBundle.globalException.message#:#thisBundle.globalException.detail#"
+				);
+				print.line( prependLF( "<ERROR::>#message#" ) );
+
+				// ACF has an array for the stack trace
+				if ( isSimpleValue( thisBundle.globalException.stacktrace ) ) {
+					print.line( prependLF( "<LOG::-Stacktrace>#escapeLF( thisBundle.globalException.stacktrace )#" ) );
+				}
+			}
+
+			// Generate reports for each suite
+			for ( var suiteStats in thisBundle.suiteStats ) {
+				genSuiteReport( suiteStats = suiteStats, bundleStats = thisBundle, print = print );
+			}
+		}
+	}
+
+	/**
+	 * Recursive Output for suites
+	 * @suiteStats Suite stats
+	 * @bundleStats Bundle stats
+	 * @print The print Buffer
+	 */
+	function genSuiteReport( required suiteStats, required bundleStats, required print ){
+		print.line( prependLF( "<DESCRIBE::>#arguments.suiteStats.name#" ) );
+
+		for ( local.thisSpec in arguments.suiteStats.specStats ) {
+			print.line( prependLF( "<IT::>#local.thisSpec.name#" ) );
+
+			if ( local.thisSpec.status == "passed" ) {
+				print.line( prependLF( "<PASSED::>Test Passed" ) );
+			} else if ( local.thisSpec.status == "failed" ) {
+				print.line( prependLF( "<FAILED::>#escapeLF( local.thisSpec.failMessage )#" ) );
+			} else if ( local.thisSpec.status == "error" ) {
+				print.line( prependLF( "<ERROR::>#escapeLF( local.thisSpec.error.message )#" ) );
+
+				var errorStack = [];
+				// If there's a tag context, show the file name and line number where the error occurred
+				if (
+					isDefined( "local.thisSpec.error.tagContext" ) && isArray( local.thisSpec.error.tagContext ) && local.thisSpec.error.tagContext.len()
+				) {
+					errorStack = thisSpec.error.tagContext;
+				} else if (
+					isDefined( "local.thisSpec.failOrigin" ) && isArray( local.thisSpec.failOrigin ) && local.thisSpec.failOrigin.len()
+				) {
+					errorStack = thisSpec.failOrigin;
+				}
+
+				if ( errorStack.len() ) {
+					var stacktrace = errorStack
+						.slice( 1, 5 )
+						.map( function( item ){
+							return "at #item.template#:#item.line#";
+						} )
+						.toList( "<:LF:>" );
+					print.line( prependLF( "<LOG::-Stacktrace>#stacktrace#" ) );
+				}
+			} else {
+				print.line( prependLF( "<ERROR::>Unknown test status: #local.thisSpec.status#" ) );
+			}
+
+			print.line( prependLF( "<COMPLETEDIN::>#local.thisSpec.totalDuration#" ) );
+		}
+
+		// Handle nested Suites
+		if ( arguments.suiteStats.suiteStats.len() ) {
+			for ( local.nestedSuite in arguments.suiteStats.suiteStats ) {
+				genSuiteReport( local.nestedSuite, arguments.bundleStats, print )
+			}
+		}
+
+		print.line( prependLF( "<COMPLETEDIN::>#arguments.suiteStats.totalDuration#" ) );
+	}
+
+	private function escapeLF( required text ){
+		return replace( text, chr( 10 ), "<:LF:>", "all" );
+	}
+
+	private function prependLF( required text ){
+		return "#chr( 10 )##text#";
+	}
+
+}

LICENSE.md

@@ -0,0 +1,21 @@
+MIT License
+
+Copyright (c) 2020 Qualified Inc.
+
+Permission is hereby granted, free of charge, to any person obtaining a copy
+of this software and associated documentation files (the "Software"), to deal
+in the Software without restriction, including without limitation the rights
+to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
+copies of the Software, and to permit persons to whom the Software is
+furnished to do so, subject to the following conditions:
+
+The above copyright notice and this permission notice shall be included in all
+copies or substantial portions of the Software.
+
+THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
+AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
+OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
+SOFTWARE.

README.md

@@ -0,0 +1,10 @@
+## testbox-codewars
+
+- `CodewarsReporter`: Custom reporter for TestBox to produce Codewars format
+- `TestRunner`: Runs TestBox tests and produces output for Codewars
+
+### Usage
+
+```
+box task run TestRunner
+```

TestRunner.cfc

@@ -0,0 +1,37 @@
+/**
+ * Runs TestBox test and outputs in Codewars format.
+ * To use, run:
+ *     box task run TestRunner
+ */
+component {
+
+	function run(){
+		// Bootstrap TestBox framework
+		filesystemUtil.createMapping( "/testbox", getCWD() & "/testbox" );
+
+		// Create TestBox and run the tests
+		testData = new testbox.system.TestBox()
+			.runRaw(
+				directory = {
+					// Find all CFCs in this directory that ends with Test.
+					mapping : filesystemUtil.makePathRelative( getCWD() ),
+					recurse : false,
+					filter = function( path ){
+						return path.reFindNoCase( "Test.cfc$" );
+					}
+				}
+			)
+			.getMemento();
+
+		createObject( "CodewarsReporter" ).render( print, testData );
+
+		// Flush the buffer
+		print.toConsole();
+
+		// Set exit code to 1 on failure
+		if ( testData.totalFail || testData.totalError ) {
+			return 1;
+		}
+	}
+
+}