clickhouse_database - errors

[rmalenko]

Could you help me, please, and provide more details about how to use database?
If I use this

clickhouse_database { 'my_database':
  ensure => 'present',
}

I have got the error message

Error: Could not prefetch clickhouse_database provider 'clickhouse': Execution of '/usr/bin/clickhouse-client -c /root/.clickhouse-client/config.xml -q show databases' returned 1: Poco::Exception. Code: 1000, e.code() = 0, e.displayText() = File not found: /root/.clickhouse-client/config.xml
Error: Failed to apply catalog: Execution of '/usr/bin/clickhouse-client -c /root/.clickhouse-client/config.xml -q show databases' returned 1: Poco::Exception. Code: 1000, e.code() = 0, e.displayText() = File not found: /root/.clickhouse-client/config.xml

[BEa45xz]

I have got the same message too. as soon as I describe a database it refuses to compile on master
because of respective missing file.

defining to install client explicitly (install_client => true,) wont create the config.xml which the provider autorequires but doesnt create. the clickhouse_client.caller fails to execute because config file -c /root/.clickhouse-client/config.xml is expected but nonexistant.

[olevole]

+1

[MaxFedotov]

Can you please share your manifest or hiera data, so i would try to reproduce this issue

[olevole]

Clean/Fresh CentOS 7 installation, manifest from the sample, e.g.:

hiera data:

classes:
  - dstock_clickhouse

dstock_clickhouse module manifest:

class dstock_clickhouse()
{

  class { 'clickhouse::server':
    service_ensure  => 'running',
    service_enabled => true,
    manage_service  => true,
    manage_repo => true,
    users => {
      myuser => {
        password => '02472d6a1e23f73b37481bbd67949a5d16cbaf3d71770696f20a0cd773a2e682',
      }
    }
  } -> clickhouse_database { 'my_database':
    ensure => 'present',
  }

}

[olevole]

[MaxFedotov]

@olevole yeah, that seems like a known thing. The problem here is that different installations had different ways to generate and store passwords for users (for example, we use vault). So in order to create a database we need credentials for default user. In our environment, we use a wrapper for this manifest, where we first create a default user in vault and then add it to clickhouse config and to client config. To achieve this, you can use something like this

class dstock_clickhouse()
{
  $default_user_password = 'some_password'

  class { 'clickhouse::server':
    service_ensure  => 'running',
    service_enabled => true,
    manage_service  => true,
    manage_repo => true,
    users => {
      myuser => {
        password => '02472d6a1e23f73b37481bbd67949a5d16cbaf3d71770696f20a0cd773a2e682',
      },
      default => {
        password => $default_user_password,
        quota    => 'default',
        profile  => 'default',
        networks => {
          ip => ['::/0']
        }
      }
    }
  }
  
  file { '/root/.clickhouse-client':
    ensure => directory,
    owner  => 'root',
    group  => 'root',
  }

  $config_file_template='<config>\n\t<user>default</user>\n\t<password><%= $password %></password>\n</config>'

  file { '/root/.clickhouse-client/config.xml':
    ensure  => file,
    owner   => 'root',
    group   => 'root',
    content => inline_epp($config_file_template, {'password' => $default_user_password }),
    require => File['/root/.clickhouse-client']
  }
  
  clickhouse_database { 'my_database':
    ensure  => 'present',
    require => File['/root/.clickhouse-client/config.xml']
  }
}

I will also add this note to README.MD tomorrow, in order to prevent future problems

[olevole]

@MaxFedotov Thanks! It works for me ( slightly adjusted version above ^^ ):

  $default_user_password = 'some_password'

  class { 'clickhouse::server':
    service_ensure  => 'running',
    service_enabled => true,
    manage_service  => true,
    manage_repo => true,
    users => {
      myuser => {
        password => $default_user_password,
        quota    => 'default',
        profile  => 'default',
        networks => {
          ip => ['::/0']
        }
      }
    }
  }

  file { '/root/.clickhouse-client':
    ensure => directory,
    owner  => 'root',
    group  => 'root',
  }

  $config_file_template='<config>\n\t<user>myuser</user>\n\t<password><%= $default_user_password %></password>\n</config>'

  file { '/root/.clickhouse-client/config.xml':
    ensure  => file,
    owner   => 'root',
    group   => 'root',
    content => inline_epp($config_file_template, {'password' => $default_user_password }),
    require => File['/root/.clickhouse-client']
  }

  clickhouse_database { 'my_database':
    ensure  => 'present',
    require => File['/root/.clickhouse-client/config.xml']
  }

[olevole]

as I understand it, this pull request ( #5 ) also solves this problem by changing the path from:

    clickhouse_raw(['-c', '/root/.clickhouse-client/config.xml',

to

    clickhouse_raw(['-c', '/etc/.clickhouse-client/config.xml',

in lib/puppet/provider/clickhouse.rb, @butlerx ?

[butlerx]

Yes that's where I found the default config after installing from package manager